User:ChristianSW/Examples

Observations by observer with links to iNaturalist

The following query uses these:

• P3
• P6

PREFIX wbt: <http://biodiversity.wiki.opencura.com/prop/direct/>
PREFIX wb: <http://biodiversity.wiki.opencura.com/entity/>
PREFIX observer: <https://www.inaturalist.org/people/>

SELECT DISTINCT ?iNatlink WHERE {
   ?observation wbt:P3 observer:christiansw .
   ?observation wbt:P6 ?iNatlink .
}

Try it!

Single observation with location and link to iNaturalist

The following query uses these:

• P6
• P8
• Q124485

#defaultView:Map

PREFIX wb: <http://biodiversity.wiki.opencura.com/entity/>
PREFIX wbt: <http://biodiversity.wiki.opencura.com/prop/direct/>

SELECT ?location ?iNatlink WHERE {
  VALUES ?observation {wb:Q124485}
   ?observation wbt:P8 ?location ;
                wbt:P6 ?iNatlink .
}

Try it!

Link to German Wikipedia

The following query uses these:

• P11
• P6
• P8
• P9
• Q124625

#defaultView:Map

PREFIX wb: <http://biodiversity.wiki.opencura.com/entity/>
PREFIX wbt: <http://biodiversity.wiki.opencura.com/prop/direct/>

SELECT ?location ?iNatlink ?wikipedia WHERE {
  VALUES ?observation {wb:Q124625}
   ?observation     wbt:P8  ?location ;
                    wbt:P6  ?iNatlink ;
                    wbt:P9  ?scientific_name .
   ?scientific_name wbt:P11 ?wikidata_mapping .
SERVICE <https://query.wikidata.org/sparql> {
    ?wikipedia schema:about ?wikidata_mapping . 
    ?wikipedia schema:inLanguage "de" .
    ?wikipedia schema:isPartOf <https://de.wikipedia.org/> .
    }
}

Try it!

Link to Wikispecies

The following query uses these:

• P11
• P6
• P8
• P9
• Q131704

#defaultView:Map

PREFIX wb: <http://biodiversity.wiki.opencura.com/entity/>
PREFIX wbt: <http://biodiversity.wiki.opencura.com/prop/direct/>

SELECT ?location ?iNatlink ?wikispecies WHERE {
  VALUES ?observation {wb:Q131704}
   ?observation     wbt:P8  ?location ;
                    wbt:P6  ?iNatlink ;
                    wbt:P9  ?scientific_name .
   ?scientific_name wbt:P11 ?wikidata_mapping .
SERVICE <https://query.wikidata.org/sparql> {
    ?wikispecies schema:about ?wikidata_mapping . 
    ?wikispecies schema:isPartOf <https://species.wikimedia.org/> .
    }
}

Try it!

My Coccinellidae

The following query uses these:

• P11
• P3
• P6
• P8
• P9
• Q128695
• Q5053
• Q5526
• Q96351
• Q97245

#defaultView:Map

PREFIX wbt: <http://biodiversity.wiki.opencura.com/prop/direct/>
PREFIX wb: <http://biodiversity.wiki.opencura.com/entity/>
PREFIX observer: <https://www.inaturalist.org/people/>

SELECT DISTINCT ?location ?iNatlink ?layer WHERE {
   ?observation     wbt:P3  observer:christiansw ;
                    wbt:P8  ?location ;
                    wbt:P6  ?iNatlink ;
                    wbt:P9  ?scientific_name .
   ?scientific_name wbt:P11 ?wikidata_mapping .
FILTER(?scientific_name IN (wb:Q5053, wb:Q5526, wb:Q97245, wb:Q128695, wb:Q96351)).
SERVICE <https://query.wikidata.org/sparql> {
   ?wikidata_mapping rdfs:label ?label FILTER (lang(?label) = "de") .
   BIND(?label AS ?layer).
    }
}

Try it!