User:ChristianSW/Snippets

GBIF occurrence link

PREFIX wb: <http://biodiversity.wiki.opencura.com/entity/>
PREFIX wbt: <http://biodiversity.wiki.opencura.com/prop/direct/>

SELECT ?GBIFlink  WHERE {
  VALUES ?observation {wb:Q120840}
   ?observation wbt:P14 ?GBIF_ID .
  BIND(URI(CONCAT("https://www.gbif.org/occurrence/", STR(?GBIF_ID))) AS ?GBIFlink) 
}

Try it!

Wikidata: States of Germany with iNaturalist Search URLs

#defaultView:Map{"hide":"?coord"}

SELECT ?placename ?pic ?coord ?iNatlinkI ?iNatlinkII  WHERE {
SERVICE <https://query.wikidata.org/sparql> {
  ?place wdt:P31   wd:Q1221156 ;
         wdt:P7471 ?iNat_place_ID ;
         wdt:P625  ?coord .
OPTIONAL { ?place wdt:P18 ?pic . }
BIND(URI(CONCAT("https://www.inaturalist.org/places/", STR(?iNat_place_ID))) AS ?iNatlinkI)
BIND(URI(CONCAT("https://www.inaturalist.org/observations?subview=grid&view=species&place_id=", STR(?iNat_place_ID))) AS ?iNatlinkII)
  ?place rdfs:label ?placename FILTER (lang(?placename) = "de") .
  }
}

Try it!

Sophox -> Biodiversity on Opencura

#defaultView:Map

PREFIX wbt: <http://biodiversity.wiki.opencura.com/prop/direct/>
PREFIX observer: <https://www.inaturalist.org/people/>

SELECT ?location ?iNatlink WHERE {
  SERVICE <https://biodiversity.wiki.opencura.com/query/sparql> {
   ?observation wbt:P3 observer:christiansw ;
                wbt:P8 ?location ;
                wbt:P6 ?iNatlink .
  }
}

Sophox Query

Wikidata -> Sophox -> Biodiversity on Opencura

#defaultView:Map

PREFIX wbt: <http://biodiversity.wiki.opencura.com/prop/direct/>
PREFIX observer: <https://www.inaturalist.org/people/>

SELECT ?location ?iNatlink WHERE {
  SERVICE <https://sophox.org/sparql> {
  SERVICE <https://biodiversity.wiki.opencura.com/query/sparql> {
   ?observation wbt:P3 observer:christiansw ;
                wbt:P8 ?location ;
                wbt:P6 ?iNatlink .
  }}
}

Wikidata Query